Projekt-Anfragen: Tel: 07022/9319004 info@CodeDocu.de Software Entwicklung in C# WPF Asp.Net Core Vba Excel Word SQL-Server EF Linq, UWP Net
#

Excel vba Code: Afo aktivieren, deaktivieren und Daten aktualisieren

 

Vba Code zum anschalten und ausschalten der Afo in Excel

File://C:\Program Files (x86)\SAP BusinessObjects\Office Addin\SSapExcelAddin.vsto|vstolocal

 

Option Explicit

 

'***********< SAP >****************

 

'*Fehlerbehebung SAP nach SAPExecuteCommand:

'*Die Ausführung des Codes wurde unterbrochen

'*Behebung auf vba Codeseite: Strg+Pause, Strg+Pause, F5

'*behebt das Fehlerverhalten. Scheint ein Bug in vba zu sein

 

 

Public Sub SAP_Afo_An_Daten_aktualisieren()

    SAP_Analysis_aktivieren

    SAP_Daten_aktualisieren

End Sub

 

Public Sub SAP_Afo_AnAus_Daten_aktualisieren()

    SAP_Analysis_aktivieren

    SAP_Daten_aktualisieren

    SAP_Analysis_deaktivieren

End Sub

 

 

  

Public Sub SAP_Analysis_aktivieren()

    '------------< SAP_Analysis_aktivieren() >------------

    '*Suche COM-Addin=Analysis und aktiviere mit Connect=true

    Application.StatusBar = "suche Afo.."

   

    Dim addin As COMAddIn

    For Each addin In Application.COMAddIns

        Dim sAddin As String

        sAddin = addin.Description

        If sAddin = "Analysis" Then

            '< anschalten >

            Application.StatusBar = Now & " Afo wird aktiviert.."

            addin.Connect = True

            Application.StatusBar = Now & " Afo ist aktiviert."

            Exit Sub    'abbruch

            '</ anschalten >

        End If

    Next

   

    MsgBox "Afo Addin wurde nicht gefunden", vbInformation, "AfO check"

    Application.StatusBar = Now & " Afo Addin nicht gefunden."

    '------------</ SAP_Analysis_aktivieren() >------------

End Sub

 

Public Sub SAP_Analysis_deaktivieren()

    '------------< SAP_Analysis_deaktivieren() >------------

    '*Suche COM-Addin=Analysis und aktiviere mit Connect=true

    Dim addin As COMAddIn

    For Each addin In Application.COMAddIns

        Dim sAddin As String

        sAddin = addin.Description

        If sAddin = "Analysis" Then

            Application.StatusBar = Now & " Afo wird deaktiviert.."

           

            '< anschalten >

            addin.Connect = False

            Application.StatusBar = Now & " Afo wurde deaktiviert"

            Exit Sub    'abbruch

            '</ anschalten >

        End If

    Next

   

    MsgBox "Afo Addin wurde nicht gefunden", vbInformation, "AfO check"

    Application.StatusBar = Now & " Afo Addin nicht gefunden."

    '------------</ SAP_Analysis_deaktivieren() >------------

End Sub

 

 

 

Public Sub SAP_Daten_aktualisieren()

    '------------< SAP_Daten_aktualisieren() >------------

   

    Application.StatusBar = Now & " Daten auf Afo-Blättern werden aktualisiert.."

    DoEvents

   

    Dim sap_Result  As Long

    sap_Result = Application.Run("SAPExecuteCommand", "Refresh")  ', "All"

   

    If sap_Result <> 0 Then

        Application.StatusBar = Now & " Problem beim Aktualisieren der SAP Daten "

        MsgBox "Fehler beim Aktualisieren der SAP Daten. SAPCode= " & sap_Result, vbCritical

    Else

        Application.StatusBar = Now & " Fertig: SAP Daten wurden erfolgreich aktualisiert "

    End If

    '------------</ SAP_Daten_aktualisieren() >------------

End Sub

 

 

Mobile
»
SAP Excel Makro: Hierarchie Level auswerten
»
Excel vba Code: Afo aktivieren, deaktivieren und Daten aktualisieren
»
Excel AfO automatisch an und ausschalten
»
Excel AfO: Anzahl der Datenmenge erhöhen

.

Jobs, Projekte, Angebote für Freiberufler, Selbstständig an Info@CodeDocu.de